Ось приклад:

package
{
	public class Flea
	{
		public function Flea()
		{
			if(this.hasOwnProperty("startJump"))
				(this as Object).startJump()
		}
	}
}

В іншому класі того ж проекту при натисканні Ctrl+Space ми не побачимо клас Flea.

Також в самому класі не будуть працювати більшість можливостей Flex Builder, як наприклад перехід по F3, або Ctrl+o.

Такого не станеться, якщо використовувати фігурні дужки для обрамлення тіла оператора if :)

if(this.hasOwnProperty("startJump"))
{
	(this as Object).startJump()
}

Результат:

var _num:Number = 0;
function get num():Number
{
	return _num;
}
function set num(value:Number):void
{
	_num = value;
}

Створюємо іще одну змінну:

var num2:Number = num++;

Отримуєм помилку компіляції:

1067: Implicit coercion of a value of type void to an unrelated type Number.

Вважаю що виходить так:

var num2:Number = set num(get num() + 1);

А так як результат set num() є void, то ми і отримуємо помилку.

var xx:XML = <root attr="1"></root>;
switch(xx.@attr)
{
	case 1:
		trace("Case: 1");
	break;
	case "1":
		trace("Case: 2");
	break;
	default:
		trace("Default");
}

Що буде в output?

В output буде

Default

Тому що xx.@attr is XMLList.

З подібним треба бути обережним, т.я. особисто я два! рази витрачав по 1-2 години, щоб зловити помилку.

При роботі з XML намагайтесь використовувати зведення типів, якщо Вам потрібний String або Number. Тобто краще написати так:

switch( xx.@attr.toString() )

<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" width="400" height="300">
	<mx:TextInput text="{textInputText}" />
	<mx:String id="textInputText" />
</mx:Canvas>

Але при цьому зв’язування є одностороннім, тобто, в наведеному прикладі, якщо користувач введе текст в поле, то змінна textInputText не зміниться. На допомогу приходить теґ <Binding>.

<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" width="400" height="300">
	<mx:TextInput id="ti" text="{textInputText}" />
	<mx:String id="textInputText" />
	<mx:Binding source="ti.text" destination="textInputText" />
</mx:Canvas>

Єдиний мінус в тому, що треба вигадувати id для TextInput :)

Оновлення:

Виявляється, що можна зробити простіше :)

<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" width="400" height="300">
	<mx:TextInput id="ti" text="{textInputText}" />
	<mx:String id="textInputText">{ti.text}</mx:String>
</mx:Canvas>

Це не позбавляє нас від вигадування id, але зберігає одну строчку коду. А <binding> можна використовувати для зв’язування до більш ніж одного об’єкту.

Він робить дивовижну річ. Після “запуску” видає в output імена УСІХ! методів які виконуються, з іменами класів, до яких належать ці методи. Клас не документовано, тобто як з ним працювати не знаю (google теж нічого не каже), але методами спроб та помилок щось таки вдалось зрозуміти.

Ось усі його методи (клас статичний, тобто усі методи статичні):

• Trace.setLevel(l:int, target:int=2):Object
• Trace.getLevel(target:int=2):int
• Trace.setListener(f:Function):Object
• Trace.getListener():Function;

Trace.setLevel(l:int, target:int=2):Object

Виставляє рівень віщування, та ціль віщування.

Першим параметром може бути одна з констант:

• Trace.METHODS_AND_LINES_WITH_ARGS = 4
  • Назва методу з вхідними параметрами та номер строчки в коді зі шляхом до класу, в якому виконався метод
• Trace.METHODS_AND_LINES = 3
  • Назва методу та номер строчки
• Trace.METHODS_WITH_ARGS = 2
  • Назва методу з вхідними параметрами
• Trace.METHODS = 1
  • Тільки назва методу
• Trace.OFF = 0
  • Вимкнуто

Другим параметром може бути:

• Trace.LISTENER = 2
  • Віщувати у функцію, яка буда додана, за допомогою setListener().
• Trace.FILE = 1
  • Віщувати у output.

Trace.getLevel(target:int=2):int

Повертає рівень віщування для цілі.

Trace.setListener(f:Function):Object

Виставляє функцію для віщування при цілі віщування = Trace.LISTENER.

Функція має приймати 4 параметри:

private function traceListener(
	fileInfo:String,
	lineNumber:String,
	classAndMethod:String,
	methodArguments:String
):void

fileInfo – тека, де знаходиться файл + “;” + щось іще (в мене була пуста строчка) :) + “;” + ім’я файлу.

Приклад: “D:\Projects\ForTestsF3\src;;ForTestsF3.mxml”

lineNumber – номер строчки

classAndMethod – повне ім’я класу + (“/” || “$/” ) + ім’я методу.

Приклади: “flash.display::DisplayObjectContainer/addChild”

“flash.trace::Trace$/setListener” – “$/” використовується, якщо визваний метод – статичний

methodArguments -вхідні параметри методу, розділені комою (,). Але якщо параметри методу задано за допомогою rest оператору (…), то вони показані не будуть.

Trace.getListener():Function

Повертає заданий раніше лістенер.

Ось приклад:

import flash.trace.Trace;
function test(t:String):String
{
	return t;
}
Trace.setLevel(Trace.METHODS_WITH_ARGS, Trace.FILE);
var st:String = "hello!";
test(st);
stop();

В output отримаєте:

	14554003 AVMINF: MTHD Untitled_fla::MainTimeline/test ("hello!") @ 0x042F0300
	4554004 AVMINF: MTHD flash.display::MovieClip/stop () @ 0x0EF004D0

Дуже дякую 7thsky за допомогу!

	NativeMenu.display(stage:Stage, stageX:Number, stageY:Number):void

Все було б добре, але є одне але :(

Як Ви бачите метод display() приймає першим параметром Stage, але у SystemTrayIcon немає stage :( Тобто, якщо нам потрібно відобразити меню біля трею (за допомогою display()), то треба використовувати Application.application.stage, але тоді треба бути поміркувати як розташувати меню :) Адже координати SystemTrayIcon невідомі…

	public static function init(root:DisplayObject):void

Викличе її SystemManager.

У допомозі Flex є згадки про цей метатеґ, знайти їх можна виконавши пошук по слову mixin :)

Спочатку створимо у Flash IDE флешку, головним класом якої буде, наприклад, assets.Flea. В цьому класі є метод startJumping(), який просто починає програвання флешки. Назвемо файл flea.swf.

Тепер вбудуємо flea.swf в будь-який клас у Flex-проекті:

	[Embed("assets/flea.swf", mimeType="application/octet-stream")]
	private var FleaAsset:Class;

mimeType=”application/octet-stream” дає зрозуміти компілятору Flex, що вбудування потрібно робити без будь-якої конвертації даних.

Тепер в FleaAsset ми маємо клас ByteArrayAsset, тобто, практично ByteArray.

Далі завантажуємо екземпляр FleaAsset до Loader за допомогою loadBytes():

	var currLoader:Loader = new Loader();
	var ldrContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain);
	currLoader.loadBytes( new FleaAsset(), ldrContext );

ldrContext ми використовуємо, щоб бути впевненими, що клас, який знаходиться в FleaAsset буде тим самим, що і в Flex проекті.

Далі, щоб клас із FleaAsset з’явився для нашого використання, нам потрібно почекати один кадр. Це не дуже добре, але як це обійти я не знаю.

	var sprite:Sprite = new Sprite();
	sprite.addEventListener(Event.ENTER_FRAME, enterFrameHandler);

Далі, ми просто створюємо екземпляр класу assets.Flea та використовуємо його як забажаємо. Уся графічна частина цього класу, яку ми створили у Flash IDE, буде присутня :)

import assets.Flea;
function enterFrameHandler(event:Event):void
{
	var flea:Flea = new Flea();
	addChild(flea);
	flea.startJumping();
	sprite.removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
}

Я зробив приклад такої собі бібліотеки, яка може спростити роботу з убудованими swf.

Щоб знати більше раджу почитати це (англійською):

• Про теґ [Embed] та про mimeType які підтримує Flex
• Про ApplicationDomain і навіщо він потрібен
• Трішки про класи *Asset
• Приклад вбудування XML

[SWF(width="800", height="600", frameRate="30", backgroundColor="#FFFFFF")]

Помістіть його перед головним класом.

Ось, на мою думку, найелегантніша реалізація (підказали Адобовці):

public function removeAllChildren():void
{
	while (numChildren > 0)
		removeChildAt(0);
}