Олег (він же a_[w]) потішив іще однією швидкісною блохою:

var obj:Object = {p:true};
var r:Boolean = false;
var pn:String = 'p';
var t:Number = getTimer();
var i:uint;
for(i=0; i<1000000; i++) r = obj.hasOwnProperty('p');
trace("hasOwnProperty('p'): " + (getTimer()-t)); // 275
t = getTimer();
for(i=0; i<1000000; i++) r = obj.hasOwnProperty(pn);
trace("hasOwnProperty(pn): " + (getTimer()-t)); // 271
t = getTimer();
for(i=0; i<1000000; i++) r = 'p' in obj;
trace("'p' in : " + (getTimer()-t)); // 96
t = getTimer();
for(i=0; i<1000000; i++) r = pn in obj;
trace("pn in : " + (getTimer()-t)); // 97

Результат: майже в 3 рази.

Ви, напевно, помічали попередження Flash IDE “Warning: 3551: Appending text to a TextField using += is many times slower than using the TextField.appendText() method.”, коли Ви намагались додати текст таким чином:

tf.text = tf.text + "some text";
// або tf.text += "some text";

Так от, він не бреше :)

var tf:TextField = new TextField();
tf.textColor = 0x000000;
tf.width = stage.stageWidth;
tf.multiline = true;
tf.autoSize = TextFieldAutoSize.LEFT;
tf.wordWrap = true;
addChild(tf);
tf.text = "";
var textToAppend:String = "Warning: 3551: Appending text to a TextField using += is many times slower than using the TextField.appendText() method.";
var iterations:uint = 200;
var i:uint;

var startTime:int = getTimer();

for(i=0; i<iterations; i++){
	tf.text = tf.text + textToAppend;
}
trace(getTimer() - startTime); // 1313

tf.text = "";
startTime = getTimer();

for(i=0; i<iterations; i++){
	tf.appendText(textToAppend);
}
trace(getTimer() - startTime); // 92

Як видно з трейсів, функція appendText() робить свою справу більш ніж в 14 разів швидше! Хоча, якщо зменшити прорахунки на wordWrap, то результат буде – більш ніж в два рази. Таке станеться, наприклад, якщо ви додасте, в наведеному вище прикладі, “\n” до змінної textToAppend. Але це теж не погано ;)

Якщо Ви використовуєте цей вираз:
getDefinitionByName(getQualifiedClassName(obj));

то, для прискорення виконання коду використовуйте слідуючу функцію:

import flash.utils.Proxy;
import flash.utils.getQualifiedClassName;
import flash.utils.getDefinitionByName;
import flash.system.ApplicationDomain;
function getClassDefinition(any:*):Class
{
	var cls:Object = null;
	if(any is Proxy){
		cls = getDefinitionByName(getQualifiedClassName(any));
	} else if(any is String && ApplicationDomain.currentDomain.hasDefinition(any)){
		cls = getDefinitionByName(any);
	} else{
		cls = Object(any).constructor;
	}
	return cls as Class;
}

Приріст швидкості більш ніж в 6 разів ( якщо !(any is Proxy) ).

Дякую Олегові (він же a_[w]) за знайдену швидкісну блоху :)

Далі тест на швидкість

(more…)